【初心者向け】Excel VBAでPublisherを操作する！

Excel VBAからPublisherを操作したい。

【事前設定】ExcelからPublisherライブラリを参照設定する。

ライブラリの参照設定は必須ではありませんが、やっておいて方がコードの入力補完が有効になりますし、詳細なエラーがでるのでデバッグしやすい等のメリットがあるのでやっておくことをおすすめします。

だいたい必須になるコード

まず、VBAでPublisherを操作するにはPublisherのオブジェクトの階層構造を理解する必要があります。下記の記事で解説しているので参考になさってください。

Publisherドキュメントを開く。

    'Publisherアプリのインスタンスを作成します。
    Dim pubApp As Publisher.Application
    Set pubApp = New Publisher.Application
     
   'Publisherドキュメントを開きます。
    Dim pubDoc As Publisher.Document
    Set pubDoc = pubApp.Open("C:\Users\user\Documents\文書1.pub")

Publisherドキュメントを保存する。

上書き保存

    'Publisherドキュメントを上書き保存します。
    pubDoc.Save

名前を付けて保存

    'Publisherドキュメントを名前を付けて保存します。
    pubDoc.SaveAs Filename:="C:\Users\user\Documents\文書1dup.pub"

Publisherドキュメントを閉じる。

    'Publisherドキュメントを閉じます。
    pubDoc.Close
    
    'Publisherアプリを閉じます。
    pubApp.Quit
    
    'Publisherインスタンスをメモリから解放します。
    Set pubApp = Nothing

サンプルコード

サンプルコードです。

Option Explicit

Sub Publisher()

    'Publisherアプリのインスタンスを作成します。
    Dim pubApp As Publisher.Application
    Set pubApp = New Publisher.Application
    
    
    'Publisherドキュメントを開きます。
    Dim pubDoc As Publisher.Document
    Set pubDoc = pubApp.Open("C:\Users\user\Documents\文書1.pub")
    'Publisherドキュメントのファイル名を出力。
    Debug.Print "Publisherファイル名：" & pubDoc.Name
    'Publisherドキュメントのフルパスを出力。
    Debug.Print "Publisherファイル名(フルパス)：" & pubDoc.FullName
    'Publisherドキュメントの格納フォルダを出力。
    Debug.Print "Publisher保存フォルダ：" & pubDoc.Path

    
    'Pageオブジェクトを取得します。
    Dim pubPages As Publisher.pages
    Dim pubPage1 As Publisher.page
    Dim pubPage2 As Publisher.page
    Set pubPages = pubDoc.pages
    'Page数を出力します。
    Debug.Print "ページ数：" & pubPages.Count
    'Pageを追加します。
    Set pubPage1 = pubPages.Add(Count:=1, after:=pubPages.Count)
    'Pageを複製します。
    Set pubPage2 = pubPages(1).Duplicate

        
    'Shapeオブジェクトを取得します。
    Dim pubShapes As Publisher.shapes
    Dim pubShape As Publisher.shape
    Set pubShapes = pubPages(1).shapes
    'Shapeオブジェクトの数を取得します。
    Debug.Print "1ページ目のシェイプの数：" & pubShapes.Count
    
    
    'TextRangeオブジェクトを取得します。
    Dim pubText As Publisher.TextRange
    Set pubText = pubShapes(1).TextFrame.TextRange
    Debug.Print "シェイプのテキスト：" & pubText
    'TextRangeオブジェクトのテキストプロパティにテキストをセットします。
    pubText.text = "hello world!"
    
    'Publisherドキュメントを上書き保存します。
'    pubDoc.Save
    'Publisherドキュメントを名前を付けて保存します。
    pubDoc.SaveAs Filename:="C:\Users\user\Documents\文書1dup.pub"
    
    'Publisherドキュメントを閉じます。
    pubDoc.Close
    
    'Publisherアプリを閉じます。
    pubApp.Quit
    
    'Publisherインスタンスをメモリから解放します。
    Set pubApp = Nothing

End Sub

Publisher VBAのリファレンス

https://docs.microsoft.com/ja-jp/office/vba/api/overview/publisher

まとめ

Publisherを学ぶ。

動画でPublisherの使い方を学ぼう！

VBAを学ぶ